27 Dec 2011

How to use Ultra Sonic sensor (HC-SR04), demonstration with LCD.


Result:

the HC-SR04 is different from most of those commonly seen on the market, which have 4 pins compared to 3 pins. But the operation principle is the same, transmit signal, and depends on when the signal is received to estimate the distance.


HC-SR04 not only inexpensive but also practical, use a sample AVR development boar –Arduino , with a LCD screen , you can make a easy rangefinder device , which can ranging 2cm to 400cm . (although i couldn't get it work more than 2 meters :-(    
Please don't ask me how to use LCD, as it's been explained really well on the Arduino official site, please check here:


Now first connect the circuit as below :

Physical wiring: 





Download the code below :
#include <LiquidCrystal.h>

LiquidCrystal lcd(8, 7, 6, 5, 4, 3, 2);

int pingPin = 13;
int inPin = 12;
 
void setup() {
  
  // set up the LCD's number of columns and rows: 
  lcd.begin(16, 2);
  
}
 
void loop(){
  // establish variables for duration of the ping,
  // and the distance result in inches and centimeters:
  long duration, inches, cm;
 
  // The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
  // Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
  pinMode(pingPin, OUTPUT);
  digitalWrite(pingPin, LOW);
  delayMicroseconds(2);
  digitalWrite(pingPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(pingPin, LOW);
 
  // The same pin is used to read the signal from the PING))): a HIGH
  // pulse whose duration is the time (in microseconds) from the sending
  // of the ping to the reception of its echo off of an object.
  pinMode(inPin, INPUT);
  duration = pulseIn(inPin, HIGH);
 
  // convert the time into a human readable distance
  cm = microsecondsToCentimeters(duration);
  
  // if distance is too large (probably not being measured properly)
  // will discard the result.
  if (cm > 400){
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Nothing detected");
  }
  
  else {
  
  // clear lcd content
  lcd.clear();
  // set the cursor to column 0, line 0
  // (note: line 1 is the second row, since counting begins with 0):
  lcd.setCursor(0, 0);
  lcd.print("Object detected ");
  lcd.setCursor(0, 1);
  lcd.print(cm);
  lcd.print("cm away!");
  }
 
  delay(500);
  
}
 
long microsecondsToInches(long microseconds){
  // According to Parallax's datasheet for the PING))), there are
  // 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
  // second).  This gives the distance travelled by the ping, outbound
  // and return, so we divide by 2 to get the distance of the obstacle.
  return microseconds / 74 / 2;}
 
long microsecondsToCentimeters(long microseconds){
  // The speed of sound is 340 m/s or 29 microseconds per centimeter.
  // The ping travels out and back, so to find the distance of the
  // object we take half of the distance travelled.
  return microseconds / 29 / 2;}

Reset the Arduino , then you can see the distance of object in front on the LCD.